all.include 4.86 KB
Newer Older
Jan Möbius's avatar
Jan Möbius committed
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167

################################################################################
# This is a library
################################################################################


################################################################################
# Needed Qt packages and build plugin
################################################################################

CONFIG += qt uitools opengl thread debug_and_release 

QT += opengl network script sql webkit

################################################################################
# Add toplevel directory to include path
# TOPDIR has to be specified in a .qmake.cache file in your projects toplevel 
# directory
################################################################################
INCLUDEPATH = $$quote( $${TOPDIR} )
DEPENDPATH  = $$quote( $${TOPDIR} )

################################################################################
# Define header Extension
# This will also override the header extension for uic output
# ( Do not change to += otherwise uic output will end with .h ! )
################################################################################
QMAKE_EXT_H = .hh .h

################################################################################
# Architecture detection
################################################################################
include( architecture.include )

################################################################################
# Helper functions
################################################################################
include( functions.include )

################################################################################
# Custom settings for compiler flags and similar
################################################################################
include( compiler.include)

################################################################################
# Extra target definitions
################################################################################
include( targets.include )

################################################################################
# Global package definitions
################################################################################
include( packages/packages.$${SYSTEMTYPE} )

################################################################################
# Local package definitions
# These lines will include a file from a .qmake directory inside your home.
# this file will overwrite existing setting
################################################################################

unix { 
	HOME=$$system(echo ~) 
} 
#else {
	#message( TODO : Define Home in Windows )
#}

exists( $${HOME}/.qmake/config.$${SYSTEMTYPE} ) {
	include( $${HOME}/.qmake/config.$${SYSTEMTYPE} ) 
}

################################################################################
# Set standard build directories 
# ( Everything generated while compiling will go # into a per architecture 
#   directory )
################################################################################
OBJECTS_DIR = tmp/$$BUILDDIRECTORY
MOC_DIR = tmp/$$BUILDDIRECTORY
UI_DIR = tmp/$$BUILDDIRECTORY 

################################################################################
# type definitions
################################################################################

# This function sets all parameters required to build a plugin
defineTest(Plugin) {
	unix{
		TEMPLATE = lib		
	}	
	win32 {
		TEMPLATE = vclib
		TARGET = $$replace(TARGET, - , _)
		export(TARGET)
		QMAKE_INCDIR += $${TOPDIR}/OpenFlipper/BasePlugin
		export(QMAKE_INCDIR)       
  		LIBS+= -L$${TOPDIR}/OpenFlipper/$${BUILDDIRECTORY} -lPluginLib		
		export(LIBS)
		DEPENDPATH += $${TOPDIR}/OpenFlipper/$${BUILDDIRECTORY} 
		DEFINES += ACGDLL USEACG
		export(DEFINES)
		export(DEPENDPATH)
		glut()
	}
        macx {
 		glut()
        }
	export(TEMPLATE)
	CONFIG *= plugin
	export(CONFIG)
	DESTDIR = $${TOPDIR}/OpenFlipper/Plugins/$${SYSTEMTYPE}/$${ARCHITECTURE}/$${MODE}	
	export(DESTDIR)	
	acg()
	openmesh()
	glew()
	defineTargets()
}

defineTest(Library) {
	unix{
		TEMPLATE = lib
		contains( OPERATING_SYSTEM, Darwin) {
			CONFIG -= static
			export(CONFIG)
		}
	}
	win32 {
		TEMPLATE = vclib
	}
	export(TEMPLATE)
	DESTDIR = lib/$$BUILDDIRECTORY
	export(DESTDIR)
	defineTargets()
	UI_DIR = include
	export(UI_DIR)
}

defineTest(Application) {
	unix {
		TEMPLATE = app
	}
	win32 {
		TEMPLATE = vcapp
	}
	macx {
		CONFIG -= app_bundle
		export( CONFIG )
	}
	export(TEMPLATE)
	DESTDIR = $$BUILDDIRECTORY
	export(DESTDIR)
	defineTargets()
}


defineTest(Subdirs) {
	unix {
        	TEMPLATE = subdirs
	}
	win32 {
		TEMPLATE = vcsubdirs
	}
        export(TEMPLATE)
        CONFIG += ordered
        export(CONFIG)
	defineTargets()
}